mirror of
https://github.com/phil-opp/blog_os.git
synced 2025-12-16 22:37:49 +00:00
148 lines
3.9 KiB
NASM
148 lines
3.9 KiB
NASM
; Copyright 2015 Philipp Oppermann
|
|
;
|
|
; Licensed under the Apache License, Version 2.0 (the "License");
|
|
; you may not use this file except in compliance with the License.
|
|
; You may obtain a copy of the License at
|
|
;
|
|
; http://www.apache.org/licenses/LICENSE-2.0
|
|
;
|
|
; Unless required by applicable law or agreed to in writing, software
|
|
; distributed under the License is distributed on an "AS IS" BASIS,
|
|
; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
; See the License for the specific language governing permissions and
|
|
; limitations under the License.
|
|
|
|
global start
|
|
extern long_mode_start
|
|
|
|
section .text
|
|
bits 32
|
|
start:
|
|
mov esp, stack_top
|
|
|
|
call test_multiboot
|
|
call test_cpuid
|
|
call test_long_mode
|
|
|
|
call setup_page_tables
|
|
call enable_paging
|
|
|
|
; load the 64-bit GDT
|
|
lgdt [gdt64.pointer]
|
|
|
|
; update selectors
|
|
mov ax, gdt64.data
|
|
mov ss, ax
|
|
mov ds, ax
|
|
mov es, ax
|
|
|
|
jmp gdt64.code:long_mode_start
|
|
|
|
setup_page_tables:
|
|
; map first P4 entry to P3 table
|
|
mov eax, p3_table
|
|
or eax, 0b11 ; present + writable
|
|
mov [p4_table], eax
|
|
|
|
; map first P3 entry to a huge page that starts at address 0
|
|
mov dword [p3_table], 0b10000011 ; present + writable + huge
|
|
|
|
ret
|
|
|
|
enable_paging:
|
|
; load P4 to cr3 register (cpu uses this to access the P4 table)
|
|
mov eax, p4_table
|
|
mov cr3, eax
|
|
|
|
; enable PAE-flag in cr4 (Physical Address Extension)
|
|
mov eax, cr4
|
|
or eax, 1 << 5
|
|
mov cr4, eax
|
|
|
|
; set the long mode bit in the EFER MSR (model specific register)
|
|
mov ecx, 0xC0000080
|
|
rdmsr
|
|
or eax, 1 << 8
|
|
wrmsr
|
|
|
|
; enable paging in the cr0 register
|
|
mov eax, cr0
|
|
or eax, 1 << 31
|
|
or eax, 1 << 16
|
|
mov cr0, eax
|
|
|
|
ret
|
|
|
|
; Prints `ERR: ` and the given error code to screen and hangs.
|
|
; parameter: error code (in ascii) in al
|
|
error:
|
|
mov dword [0xb8000], 0x4f524f45
|
|
mov dword [0xb8004], 0x4f3a4f52
|
|
mov dword [0xb8008], 0x4f204f20
|
|
mov byte [0xb800a], al
|
|
hlt
|
|
|
|
; Throw error 0 if eax doesn't contain the Multiboot 2 magic value (0x36d76289).
|
|
test_multiboot:
|
|
cmp eax, 0x36d76289
|
|
jne .no_multiboot
|
|
ret
|
|
.no_multiboot:
|
|
mov al, "0"
|
|
jmp error
|
|
|
|
; Throw error 1 if the CPU doesn't support the CPUID command.
|
|
test_cpuid:
|
|
pushfd ; Store the FLAGS-register.
|
|
pop eax ; Restore the A-register.
|
|
mov ecx, eax ; Set the C-register to the A-register.
|
|
xor eax, 1 << 21 ; Flip the ID-bit, which is bit 21.
|
|
push eax ; Store the A-register.
|
|
popfd ; Restore the FLAGS-register.
|
|
pushfd ; Store the FLAGS-register.
|
|
pop eax ; Restore the A-register.
|
|
push ecx ; Store the C-register.
|
|
popfd ; Restore the FLAGS-register.
|
|
xor eax, ecx ; Do a XOR-operation on the A-register and the C-register.
|
|
jz .no_cpuid ; The zero flag is set, no CPUID.
|
|
ret ; CPUID is available for use.
|
|
.no_cpuid:
|
|
mov al, "1"
|
|
jmp error
|
|
|
|
; Throw error 2 if the CPU doesn't support Long Mode.
|
|
test_long_mode:
|
|
mov eax, 0x80000000 ; Set the A-register to 0x80000000.
|
|
cpuid ; CPU identification.
|
|
cmp eax, 0x80000001 ; Compare the A-register with 0x80000001.
|
|
jb .no_long_mode ; It is less, there is no long mode.
|
|
mov eax, 0x80000000 ; Set the A-register to 0x80000000.
|
|
cpuid ; CPU identification.
|
|
cmp eax, 0x80000001 ; Compare the A-register with 0x80000001.
|
|
jb .no_long_mode ; It is less, there is no long mode.
|
|
ret
|
|
.no_long_mode:
|
|
mov al, "2"
|
|
jmp error
|
|
|
|
section .bss
|
|
align 4096
|
|
p4_table:
|
|
resb 4096
|
|
p3_table:
|
|
resb 4096
|
|
stack_bottom:
|
|
resb 64
|
|
stack_top:
|
|
|
|
section .rodata
|
|
gdt64:
|
|
dq 0 ; zero entry
|
|
.code: equ $ - gdt64 ; new
|
|
dq (1<<44) | (1<<47) | (1<<41) | (1<<43) | (1<<53) ; code segment
|
|
.data: equ $ - gdt64 ; new
|
|
dq (1<<44) | (1<<47) | (1<<41) ; data segment
|
|
.pointer:
|
|
dw $ - gdt64 - 1
|
|
dq gdt64
|