# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>

_pkgname=nfancurve
pkgname=${_pkgname}-git
pkgver=v017.r17.gb36e1c2
pkgrel=1
pkgdesc="A small and lightweight Bash script for using a custom fan curve in Linux for NVIDIA GPUs"
arch=("any")
url="https://github.com/nan0s7/nfancurve"
license=("GPL3")
depends=("bash" "nvidia" "procps")
makedepends=("git")
conflicts=("${_pkgname}")
install=${_pkgname}.install
source=(
    "${_pkgname}::git+https://github.com/nan0s7/${_pkgname}.git"
		"nfancurve.desktop"
)
sha512sums=(
    "SKIP"
    "eacb0f97ee0f1b25074060fca34637258dc239a776e7e738eaa5b0c46f365f2c08cbe41cb527708e22360b19a8e0c4cc3141bd53964531b8ce344890195ef5f4"
)

pkgver() {
    cd "${_pkgname}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
    cd "${_pkgname}"

    install -m755 -D "temp.sh" "${pkgdir}/usr/bin/nfancurve"
    install -m644 -D "config" "${pkgdir}/usr/share/doc/${_pkgname}/config.example"
    install -m644 -D "config" "${pkgdir}/etc/${_pkgname}/config"
		install -m644 -D "../nfancurve.desktop" "${pkgdir}/usr/share/applications/nfancurve.desktop"
}