From d9bcffd6267fc8151f67fc16a999845e8aaa960a Mon Sep 17 00:00:00 2001
From: Michael Kuc <michaelkuc6@gmail.com>
Date: Fri, 22 Mar 2019 12:24:13 +0000
Subject: [PATCH] Added nheko-git.

---
 nheko-git/PKGBUILD | 66 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 nheko-git/PKGBUILD

diff --git a/nheko-git/PKGBUILD b/nheko-git/PKGBUILD
new file mode 100644
index 0000000..17f5bd9
--- /dev/null
+++ b/nheko-git/PKGBUILD
@@ -0,0 +1,66 @@
+pkgname=nheko-git
+pkgver=v0.6.2.r1.g6a90ed5
+pkgrel=1
+pkgdesc="Desktop client for the Matrix protocol"
+arch=("i686" "x86_64")
+
+url="https://github.com/Nheko-Reborn/nheko"
+license=("GPL3")
+
+depends=("qt5-base" "lmdb" "qt5-multimedia" "qt5-svg" "boost" "libsodium" "openssl" "cmark" "mtxclient")
+makedepends=("git" "cmake" "gcc" "fontconfig" "qt5-tools")
+
+provides=("nheko")
+conflicts=("nheko")
+
+source=($pkgname::git://github.com/mujx/nheko.git)
+md5sums=("SKIP")
+
+pkgver() {
+  cd "$pkgname"
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "$pkgname"
+  
+  # Fix up includes to nlohmann json
+  grep -rl '#include <json.hpp>' | xargs sed -i 's|#include <json.hpp>|#include <nlohmann/json.hpp>|'
+  grep -rl '#include "json.hpp"' | xargs sed -i 's|#include "json.hpp"|#include <nlohmann/json.hpp>|'
+}
+
+build() {
+    cd "$pkgname"
+
+    rm -f cmake/FindOlm.cmake
+
+    cmake -Hdeps -B.deps -DUSE_BUNDLED_BOOST=OFF -DUSE_BUNDLED_CMARK=OFF
+    cmake --build .deps
+
+    cmake -H. -Bbuild -DCMAKE_BUILD_TYPE=Release \
+        -DLMDBXX_INCLUDE_DIR=.deps/usr/include \
+        -DTWEENY_INCLUDE_DIR=.deps/usr/include
+    cmake --build build
+}
+
+package() {
+    # Creating needed directories
+    install -dm755 "$pkgdir/usr/bin"
+    install -dm755 "$pkgdir/usr/share/pixmaps/"
+    install -dm755 "$pkgdir/usr/share/applications/"
+
+    # Program
+    install -Dm755 "$pkgname/build/nheko" "$pkgdir/usr/bin/nheko"
+
+    # Desktop launcher
+    install -Dm644 "$srcdir/$pkgname/resources/nheko-256.png" "$pkgdir/usr/share/pixmaps/nheko.png"
+    install -Dm644 "$srcdir/$pkgname/resources/nheko.desktop" "$pkgdir/usr/share/applications/nheko.desktop"
+
+    # Icons
+    local icon_size icon_dir
+    for icon_size in 16 32 48 64 128 256 512; do
+        icon_dir="$pkgdir/usr/share/icons/hicolor/${icon_size}x${icon_size}/apps"
+        install -d "$icon_dir"
+        install -m644 "$srcdir/$pkgname/resources/nheko-${icon_size}.png" "$icon_dir/nheko.png"
+    done
+}